0e7b897c73
Update all inputs, rename the KDE platform, and apply formatter changes
by running the following commands:
biome check --unsafe --write
pre-commit run --all-files
Rename the KDE platform, following local commit f47c0edcf7 ("treewide:
remove Plasma 5 support dropped upstream (#1860)") and upstream commits
[1] ("nixos/treewide: clean up some more references to deleted qt5
things") and [2] ("qt: deprecate kde6").
[1]: 31d5c4e753
[2]: 1e759786e5
Closes: https://github.com/nix-community/stylix/issues/1865
Link: https://github.com/nix-community/stylix/pull/1866
Link: https://github.com/nix-community/stylix/pull/1881
Reviewed-by: NAHO <90870942+trueNAHO@users.noreply.github.com>
Co-authored-by: Samuel Meenzen <samuel@meenzen.net>
Co-authored-by: NAHO <90870942+trueNAHO@users.noreply.github.com>
Reviewed-by: Daniel Thwaites <danth@danth.me>
64 lines
1.8 KiB
Nix
64 lines
1.8 KiB
Nix
{
|
|
perSystem =
|
|
{
|
|
pkgs,
|
|
config,
|
|
inputs',
|
|
...
|
|
}:
|
|
let
|
|
stylix-check = pkgs.writeShellApplication {
|
|
name = "stylix-check";
|
|
runtimeInputs = with pkgs; [
|
|
nix
|
|
nix-fast-build
|
|
];
|
|
text = ''
|
|
cores="$(nproc)"
|
|
system="$(nix eval --expr builtins.currentSystem --impure --raw)"
|
|
nix-fast-build \
|
|
--eval-max-memory-size 512 \
|
|
--eval-workers "$cores" \
|
|
--flake ".#checks.$system" \
|
|
--no-link \
|
|
--skip-cached \
|
|
"$@"
|
|
'';
|
|
};
|
|
|
|
# The shell should not directly depend on `packages.serve-docs`, because
|
|
# that'd build the docs before entering the shell. Instead, we want to
|
|
# build the docs only when running 'serve-docs'.
|
|
#
|
|
# For a similar reason, we can't use `self` as a reference to the flake:
|
|
# `self` represents the flake as it was when the devshell was evaluated,
|
|
# not the local flake worktree that has possibly been modified since
|
|
# entering the devshell.
|
|
build-and-run-docs = pkgs.writeShellScriptBin "serve-docs" ''
|
|
nix run .#doc
|
|
'';
|
|
in
|
|
{
|
|
devShells = {
|
|
default = pkgs.mkShell {
|
|
# Install git-hooks when activating the shell
|
|
shellHook = config.pre-commit.installationScript;
|
|
|
|
packages = [
|
|
stylix-check
|
|
build-and-run-docs
|
|
inputs'.home-manager.packages.default
|
|
config.formatter
|
|
]
|
|
++ config.pre-commit.settings.enabledPackages;
|
|
|
|
inputsFrom = [ config.treefmt.build.devShell ];
|
|
};
|
|
|
|
ghc = pkgs.mkShell {
|
|
inputsFrom = [ config.devShells.default ];
|
|
packages = [ pkgs.ghc ];
|
|
};
|
|
};
|
|
};
|
|
}
|