Address code review comments for getmail service

This patch started by addresssing the code review comments to close
https://github.com/rycee/home-manager/pull/290. However initiating a new
pull request it became clear, that home-manager changed significantly
since then.

This changes the initial pull request to be consistent with the email
account management in home-manager now. It also adds a simple test and support
for multiple accounts.

modules/programs/getmail-accounts.nix

@@ -0,0 +1,49 @@
+{ config, lib, ... }:
+
+with lib;
+
+{
+  options.getmail = {
+    enable = mkEnableOption "the getmail mail retriever for this account";
+
+    destinationCommand = mkOption {
+      type = types.nullOr types.str;
+      default = null;
+      example = "\${pkgs.maildrop}/bin/maildrop";
+      description = ''
+        Specify a command delivering the incoming mail to your maildir.
+      '';
+    };
+
+    mailboxes = mkOption {
+      type = types.nonEmptyListOf types.str;
+      default = [];
+      example = ["INBOX" "INBOX.spam"];
+      description = ''
+        A non-empty list of mailboxes. To download all mail you can
+        use the <literal>ALL</literal> mailbox.
+      '';
+    };
+
+    delete = mkOption {
+      type = types.bool;
+      default = false;
+      description = ''
+        Enable if you want to delete read messages from the server. Most
+        users should either enable <literal>delete</literal> or disable
+        <literal>readAll</literal>.
+      '';
+    };
+
+    readAll = mkOption {
+      type = types.bool;
+      default = true;
+      description = ''
+        Enable if you want to fetch all, even the read messages from the
+        server. Most users should either enable <literal>delete</literal> or
+        disable <literal>readAll</literal>.
+      '';
+    };
+
+  };
+}

modules/programs/getmail.nix

@@ -0,0 +1,59 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  accounts = filter (a: a.getmail.enable)
+    (attrValues config.accounts.email.accounts);
+
+  renderAccountConfig = account: with account;
+    let
+      passCmd = concatMapStringsSep ", " (x: "'${x}'") passwordCommand;
+      renderedMailboxes = concatMapStringsSep ", " (x: "'${x}'") getmail.mailboxes;
+      retrieverType = if imap.tls.enable
+        then "SimpleIMAPSSLRetriever"
+        else "SimpleIMAPRetriever";
+      destination = if getmail.destinationCommand != null
+        then
+        {
+          destinationType = "MDA_external";
+          destinationPath = getmail.destinationCommand;
+        }
+        else
+        {
+          destinationType = "Maildir";
+          destinationPath = "${maildir.absPath}/";
+        };
+      renderGetmailBoolean = v: if v then "true" else "false";
+    in ''
+      # Generated by Home-Manager.
+      [retriever]
+      type = ${retrieverType}
+      server = ${imap.host}
+      username = ${userName}
+      password_command = (${passCmd})
+      mailboxes = ( ${renderedMailboxes} )
+
+      [destination]
+      type = ${destination.destinationType}
+      path = ${destination.destinationPath}
+
+      [options]
+      delete = ${renderGetmailBoolean getmail.delete}
+      read_all = ${renderGetmailBoolean getmail.readAll}
+    '';
+  getmailEnabled = length (filter (a: a.getmail.enable) accounts) > 0;
+  # Watch out! This is used by the getmail.service too!
+  renderConfigFilepath = a: ".getmail/getmail${if a.primary then "rc" else a.name}";
+in
+
+  {
+    config = mkIf getmailEnabled {
+      home.file = map (a:
+        { target = renderConfigFilepath a;
+          text = renderAccountConfig a;
+        }) accounts;
+
+    };
+  }