nix/2.home-manager
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions 1

thefuck: remove module

Browse source 
Program removed upstream, let module stay around for a bit in case it came back.
We can re-introduce if the situation changes, but we have an alternative.
This commit is contained in:
Austin Horstman 2025-09-11 23:00:33 -05:00
parent 6d7c11a0ad
commit 9eab59f3e7
6 changed files with 4 additions and 171 deletions
Download patch file Download diff file Expand all files Collapse all files

4
modules/modules.nix
View file

@ -73,6 +73,10 @@ let
(lib.mkRemovedOptionModule [ "services" "keepassx" ] ''
KeePassX is no longer maintained.
'')
(lib.mkRemovedOptionModule [ "programs" "thefuck" ] ''
The corresponding package was removed from nixpkgs,
consider using `programs.pay-respects` instead.
'')
]
++ (lib.concatMap
(

76
modules/programs/thefuck.nix
View file

@ -1,76 +0,0 @@
{
config,
lib,
pkgs,
...
}:
let
inherit (lib) mkIf;
in
{
meta.maintainers = [ lib.maintainers.ilaumjd ];
options.programs.thefuck = {
enable = lib.mkEnableOption "thefuck - magnificent app that corrects your previous console command";
package = lib.mkPackageOption pkgs "thefuck" { };
enableInstantMode = lib.mkEnableOption "thefuck's experimental instant mode";
enableBashIntegration = lib.hm.shell.mkBashIntegrationOption { inherit config; };
enableFishIntegration = lib.hm.shell.mkFishIntegrationOption { inherit config; };
enableNushellIntegration = lib.hm.shell.mkNushellIntegrationOption { inherit config; };
enableZshIntegration = lib.hm.shell.mkZshIntegrationOption { inherit config; };
alias = lib.mkOption {
type = lib.types.str;
default = "fuck";
description = "Alias used to invoke `thefuck`.";
};
};
config =
let
cfg = config.programs.thefuck;
cliArgs = lib.cli.toGNUCommandLineShell { } {
alias = cfg.alias;
enable-experimental-instant-mode = cfg.enableInstantMode;
};
shEvalCmd = ''
eval "$(${cfg.package}/bin/thefuck ${cliArgs})"
'';
in
mkIf cfg.enable {
home.packages = [ cfg.package ];
programs.bash.initExtra = mkIf cfg.enableBashIntegration shEvalCmd;
programs.fish.functions = mkIf cfg.enableFishIntegration {
fuck = {
description = "Correct your previous console command";
body = ''
set -l fucked_up_command $history[1]
env TF_SHELL=fish TF_ALIAS=${cfg.alias} PYTHONIOENCODING=utf-8 ${cfg.package}/bin/thefuck $fucked_up_command THEFUCK_ARGUMENT_PLACEHOLDER $argv | read -l unfucked_command
if [ "$unfucked_command" != "" ]
eval $unfucked_command
builtin history delete --exact --case-sensitive -- $fucked_up_command
builtin history merge
end
'';
};
};
programs.zsh.initContent = mkIf cfg.enableZshIntegration shEvalCmd;
programs.nushell = mkIf cfg.enableNushellIntegration {
extraConfig = ''
alias ${cfg.alias} = ${cfg.package}/bin/thefuck $"(history | last 1 | get command | get 0)"
'';
};
};
}

5
tests/modules/programs/thefuck/default.nix
View file

@ -1,5 +0,0 @@
{
thefuck-integration-enabled = ./integration-enabled.nix;
thefuck-integration-enabled-instant = ./integration-enabled-instant.nix;
thefuck-integration-disabled = ./integration-disabled.nix;
}

23
tests/modules/programs/thefuck/integration-disabled.nix
View file

@ -1,23 +0,0 @@
{ config, ... }:
{
programs = {
thefuck = {
enable = true;
package = config.lib.test.mkStubPackage { outPath = "@thefuck@"; };
};
thefuck.enableBashIntegration = false;
thefuck.enableFishIntegration = false;
thefuck.enableZshIntegration = false;
thefuck.enableNushellIntegration = false;
bash.enable = true;
zsh.enable = true;
nushell.enable = true;
};
nmt.script = ''
assertFileNotRegex home-files/.bashrc '@thefuck@/bin/thefuck'
assertPathNotExists home-files/.config/fish/functions/fuck.fish
assertFileNotRegex home-files/.zshrc '@thefuck@/bin/thefuck'
assertFileNotRegex home-files/.config/nushell/config.nu '@thefuck@/bin/thefuck'
'';
}

24
tests/modules/programs/thefuck/integration-enabled-instant.nix
View file

@ -1,24 +0,0 @@
{ config, ... }:
{
programs = {
thefuck = {
enable = true;
package = config.lib.test.mkStubPackage { outPath = "@thefuck@"; };
enableInstantMode = true;
};
bash.enable = true;
zsh.enable = true;
};
nmt.script = ''
assertFileExists home-files/.bashrc
assertFileContains \
home-files/.bashrc \
'eval "$(@thefuck@/bin/thefuck --alias fuck --enable-experimental-instant-mode)"'
assertFileExists home-files/.zshrc
assertFileContains \
home-files/.zshrc \
'eval "$(@thefuck@/bin/thefuck --alias fuck --enable-experimental-instant-mode)"'
'';
}

43
tests/modules/programs/thefuck/integration-enabled.nix
View file

@ -1,43 +0,0 @@
{ config, ... }:
{
programs = {
thefuck = {
enable = true;
package = config.lib.test.mkStubPackage { outPath = "@thefuck@"; };
};
bash.enable = true;
fish.enable = true;
zsh.enable = true;
nushell.enable = true;
};
nmt.script = ''
assertFileExists home-files/.bashrc
assertFileContains \
home-files/.bashrc \
'eval "$(@thefuck@/bin/thefuck --alias fuck)"'
assertFileExists home-files/.config/fish/functions/fuck.fish
assertFileContains \
home-files/.config/fish/functions/fuck.fish \
'function fuck --description="Correct your previous console command"
set -l fucked_up_command $history[1]
env TF_SHELL=fish TF_ALIAS=fuck PYTHONIOENCODING=utf-8 @thefuck@/bin/thefuck $fucked_up_command THEFUCK_ARGUMENT_PLACEHOLDER $argv | read -l unfucked_command
if [ "$unfucked_command" != "" ]
eval $unfucked_command
builtin history delete --exact --case-sensitive -- $fucked_up_command
builtin history merge
end
end'
assertFileExists home-files/.zshrc
assertFileContains \
home-files/.zshrc \
'eval "$(@thefuck@/bin/thefuck --alias fuck)"'
assertFileExists home-files/.config/nushell/config.nu
assertFileContains \
home-files/.config/nushell/config.nu \
'alias fuck = @thefuck@/bin/thefuck $"(history | last 1 | get command | get 0)"'
'';
}